Khắc phục lỗi khi Update AVG

Nếu bạn đang dùng AVG trong hệ thống thì việc update nó là rất cần thiết. Nhưng có khi nào bạn update bị lỗi không? Mình đã mắc phải sai lầm này và tìm cách khắc phục còn nguyên nhân thì mình chẳng biết do đâu.
Bạn cần phải đổi tên/xóa bỏ các files tạm thời CTF từ C:\Documents and Setting\All Users\Application Data\Avg8\Update\download… xóa bỏ tất các các file dạng *.bin trong đó nếu bạn muốn chạy lại bản Update từ đầu. Sau đó xóa luôn 2 file dạng *.Ctf là avginfoavi.Ctf và avginfowin.Ctf cũng trong thư mục này. Nhưng bạn chú ý rằng thư mục này nằm ở chế độ ẩn, nên bạn phải hiển thị các tập tin ẩn để xem dữ liệu trong thư mục này.
Nếu bạn dùng Windows Vista, bạn xóa các tập tin dạng *.Ctf từ thư mục C:\ProgramData\avg8\Update\download

Cách khác để làm việc này là chạy 1 ứng dụng bằng Script, nó sẽ tự động hóa nhiệm vụ này. Trước hết bạn copy đoạn code này vào Notepad và lưu lại với tên là DelAvgCft.vbs

'Created on June 14 2009
'Homepage: http://ngocthinhpro.blogspot.com
'""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
If GetOS = "Windows XP" Then
DelCTFs
End If

If GetOS = "Windows Vista/7" Then
If WScript.Arguments.length =0 Then
Set objShell = CreateObject("Shell.Application")
objShell.ShellExecute "wscript.exe", """" & _
WScript.ScriptFullName & """" & " uac","", "runas", 1
Else
DelCTFs
End If
End If

Sub DelCTFs
Const CSIDL_COMMON_APPDATA = &H23
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(CSIDL_COMMON_APPDATA)
Set objFolderItem = objFolder.Self
strPath = objFolderItem.Path
strFiles = strPath & "\Avg8\update\download\*.ctf"
On Error Resume Next
objFSO.DeleteFile(strFiles), True
If Err.number = 0 then
Msgbox "Successfully deleted the .CTF files. Try updating AVG now.", , "Avg 8 Update Fix - ngocthinhpro.blogspot.com"
elseif Err.number = 53 then
Msgbox "No .CTF files were found. No changes made.", , "Avg 8 Update Fix - ngocthinhpro.blogspot.com"
else
Msgbox "Error " & Err.number & ": " & Err.Description, , "Avg 8 Update Fix - ngocthinhpro.blogspot.com"
end if
End Sub

Function GetOS
Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
".\root\cimv2")
Set colOS = objWMI.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOS in colOS
If instr(objOS.Caption, "Vista") Or instr(objOS.Caption, "Windows 7") Then
GetOS = "Windows Vista/7"
elseIf instr(objOS.Caption, "Windows XP") Then
GetOS = "Windows XP"
End If
Next
End Function


Sau đó chạy file này, các tập tin AVG *.CTF sẽ được xóa tự động ngay tức khắc.

Đoạn code này hoạt động tốt trong Windows XP và Vista
Sau đó Update lại như bình thường
Chúc thành công!!


Trấn Phiên